Skip to content

earthly: move to earthbuild 0.8.17 #463269

New issue

Have a question about this project? Sign up for a free GitHub account to open an issue and contact its maintainers and the community.

Sign up for GitHub

By clicking “Sign up for GitHub”, you agree to our terms of service and privacy statement. We’ll occasionally send you account related emails.

Already on GitHub? Sign in to your account

Open
konradmalik wants to merge 1 commit into
base: master
Choose a base branch
from
Open

earthly: move to earthbuild 0.8.17 #463269

Show file tree
Hide file tree
Changes from all commits
Commits
Show all changes
1 commit
Select commit
File filter

Filter by extension

Filter by extension
Conversations
Failed to load comments.
Loading
Jump to
Jump to file
Failed to load files.
Loading
Diff view
Diff view
72 changes: 72 additions & 0 deletions pkgs/by-name/ea/earthbuild/package.nix
View file
Open in desktop
Original file line number Diff line number Diff line change
@@ -0,0 +1,72 @@
{
lib,
buildGoModule,
fetchFromGitHub,
stdenv,
testers,
}:

buildGoModule (finalAttrs: {
pname = "earthbuild";
version = "0.8.17";

src = fetchFromGitHub {
owner = "EarthBuild";
repo = "earthbuild";
rev = "v${finalAttrs.version}";
hash = "sha256-ATdNA9KjAXsxMiez3AF6TxK7OujNDABY8jB6hXeSNpc=";
};

vendorHash = "sha256-49FWzLHEbgwWOXT1uPshdY5risFHInA541Mfhu7v08A=";

__structuredAttrs = true;
# BUG: when provided as a list and __structuredAttrs is true, only the first elements gets build
# It's because the Go builder at pkgs/build-support/go/module.nix:325-326 reads $subPackages as a space-separated string
subPackages = "cmd/earthly cmd/debugger";

env.CGO_ENABLED = 0;

ldflags = [
"-s"
"-w"
"-X main.Version=v${finalAttrs.version}"
"-X main.DefaultBuildkitdImage=docker.io/earthbuild/buildkitd:v${finalAttrs.version}"
"-X main.GitSha=v${finalAttrs.version}"
]
++ lib.optionals stdenv.hostPlatform.isLinux [
"-extldflags '-static'"
];

tags = [
"dfrunmount"
"dfrunnetwork"
"dfrunsecurity"
"dfsecrets"
"dfssh"
];

postInstall = ''
mv $out/bin/debugger $out/bin/earthly-debugger
ln -s $out/bin/earthly-debugger $out/bin/earth-debugger
ln -s $out/bin/earthly $out/bin/earth
'';

passthru = {
tests.version = testers.testVersion {
package = finalAttrs.finalPackage;
version = "v${finalAttrs.version}";
};
};

meta = {
description = "Build automation for the container era";
mainProgram = "earth";
homepage = "https://earthbuild.dev/";
changelog = "https://github.com/EarthBuild/earthbuild/releases/tag/v${finalAttrs.version}";
license = lib.licenses.mpl20;
maintainers = with lib.maintainers; [
zoedsoupe
konradmalik
];
};
})
70 changes: 0 additions & 70 deletions pkgs/by-name/ea/earthly/package.nix
View file
Open in desktop

This file was deleted.

1 change: 1 addition & 0 deletions pkgs/top-level/aliases.nix
View file
Open in desktop
Original file line number Diff line number Diff line change
Expand Up @@ -651,6 +651,7 @@ mapAliases {
e17gtk = throw "'e17gtk' has been removed because it was archived upstream."; # Added 2026-01-15
e-search = throw "'e-search' has been removed due to outdated KF5 dependencies"; # Added 2026-05-01
eagle = throw "'eagle' has been removed because official support ends 2026-06-07. It depended on qt5 webengine, which was removed for its numerous security issues. For more details, see the autodesk announcement at https://www.autodesk.com/support/technical/article/caas/sfdcarticles/sfdcarticles/Autodesk-EAGLE-Announcement-Next-steps-and-FAQ.html"; # Added 2026-04-26
earthly = warnAlias "'earthly' has been discontinued. It is replaced by a community fork 'earthbuild'" earthbuild; # Added 2025-11-19
eask = throw "'eask' has been renamed to/replaced by 'eask-cli'"; # Converted to throw 2025-10-27
easyloggingpp = throw "easyloggingpp has been removed, as it is deprecated upstream and does not build with CMake 4"; # Added 2025-09-17
ebpf-verifier = warnAlias "'ebpf-verifier' has been renamed to 'prevail'" prevail; # Added 2026-04-01
Expand Down
Loading