gz-math: init at 9.1.0

pkgs/by-name/gz/gz-cmake/package.nix

@@ -11,7 +11,7 @@
   nix-update-script,
 }:
 let
-  version = "5.0.0";
+  version = "5.1.1";
   versionPrefix = "gz-cmake${lib.versions.major version}";
 in
 stdenv.mkDerivation (finalAttrs: {
@@ -22,7 +22,7 @@ stdenv.mkDerivation (finalAttrs: {
     owner = "gazebosim";
     repo = "gz-cmake";
     tag = "${versionPrefix}_${finalAttrs.version}";
-    hash = "sha256-XF7oglj9Xr6F8a+6uowrY5a040yl4FZlFfW/Y0BJwOs=";
+    hash = "sha256-bp3qaLuE/0sf6u4ZVOGsuJVkuEm2IS0zB0vHMVE0g/g=";
   };
 
   postPatch = ''

pkgs/by-name/gz/gz-math/package.nix

@@ -0,0 +1,78 @@
+{
+  lib,
+  stdenv,
+  cmake,
+  ctestCheckHook,
+  eigen,
+  fetchFromGitHub,
+  gtest,
+  gz-cmake,
+  gz-utils,
+  nix-update-script,
+  python3Packages,
+  ruby,
+  swig,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "gz-math";
+  version = "9.1.0";
+
+  src = fetchFromGitHub {
+    owner = "gazebosim";
+    repo = "gz-math";
+    tag = "gz-math${lib.versions.major finalAttrs.version}_${finalAttrs.version}";
+    hash = "sha256-Kc9g5D52+NVygYLpMf+4GFPPn2sTEfXBOC14iw39NlA=";
+  };
+
+  strictDeps = true;
+  __structuredAttrs = true;
+
+  buildInputs = [ gz-cmake ];
+
+  nativeBuildInputs = [
+    cmake
+    swig
+  ]
+  ++ (with python3Packages; [
+    python
+    pybind11
+  ]);
+
+  propagatedBuildInputs = [
+    gz-utils
+    eigen
+  ];
+
+  doCheck = true;
+
+  checkInputs = [ gtest ];
+
+  nativeCheckInputs = [
+    ctestCheckHook
+    ruby
+    python3Packages.python
+  ];
+
+  disabledTests = lib.optionals (stdenv.hostPlatform.isDarwin && stdenv.hostPlatform.isAarch64) [
+    # Non-deterministic random tests fail on aarch64-darwin
+    "GaussMarkovProcess_TEST.rb"
+    "Rand_TEST.rb"
+  ];
+
+  passthru = {
+    # bulk updater selects wrong tag
+    skipBulkUpdates = true;
+    updateScript = nix-update-script {
+      extraArgs = [ "--version-regex=gz-math(.*)" ];
+    };
+  };
+
+  meta = {
+    description = "Math classes and functions for robot applications";
+    homepage = "https://gazebosim.org/home";
+    license = lib.licenses.asl20;
+    platforms = lib.platforms.unix ++ lib.platforms.windows ++ lib.platforms.darwin;
+    maintainers = with lib.maintainers; [ guelakais ];
+  };
+})

pkgs/by-name/gz/gz-utils/package.nix

@@ -5,7 +5,7 @@
 
   # nativeBuildInputs
   cmake,
-  gz-cmake,
+  gz-cmake, # currently, gz-utils is dependent on gz-cmake
   doxygen,
   graphviz,
 

pkgs/development/python-modules/gz-math/default.nix

@@ -0,0 +1,6 @@
+{
+  pkgs,
+  toPythonModule,
+}:
+
+toPythonModule (pkgs.gz-math)

pkgs/top-level/python-packages.nix

@@ -6946,6 +6946,8 @@ self: super: with self; {
 
   gyp = callPackage ../development/python-modules/gyp { };
 
+  gz-math = callPackage ../development/python-modules/gz-math { };
+
   h11 = callPackage ../development/python-modules/h11 { };
 
   h2 = callPackage ../development/python-modules/h2 { };