cmake: Replaces CACHE variables with overridable variables.

This patch replaces every CACHE variable that has a hard-coded default
value with a overridable variable (using a new function that automatizes
its creation).

An overridable variable is a variable that uses a default value if it
doesn't already exists, either in the cache or in the environment.

Doing this enables us to update the hard-coded values by changing the
CMake files, consequently updating any existing configuration that
doesn't have an overriden value for these variables (therefore using
the default values).

Change-Id: I740ee98c0d680be4d86940968af320bc1e1a634e
Reviewed-on: http://gerrit2.aldebaran.lan/1384
Reviewed-by: philippe.martin <philippe.martin@softbankrobotics.com>
Tested-by: vincent.palancher <vincent.palancher@softbankrobotics.com>
Reviewed-by: jmonnon <jmonnon@aldebaran.com>

Author: Vincent Palancher

cmake/set_dependencies.cmake

@@ -44,42 +44,30 @@
 
 include_guard(GLOBAL)
 
-set(BOOST_VERSION 1.64
-    CACHE STRING
-    "Version of Boost to use. It will be used as the argument to the
-`find_package(Boost)` call.")
-
-set(PYBIND11_VERSION 2.5.0
-    CACHE STRING
-    "Version of pybind11 to use.")
-
-set(PYBIND11_GIT_REPOSITORY https://github.com/pybind/pybind11
-    CACHE STRING
-    "URL of the git repository from which to download pybind11. For more \
-details, see CMake `ExternalProject` module documentation of the \
-`GIT_REPOSITORY` argument.")
-
-set(PYBIND11_GIT_TAG v${PYBIND11_VERSION}
-    CACHE STRING
-    "Git branch name, tag or commit hash to checkout for pybind11. \
-For more details, see CMake `ExternalProject` module documentation of the \
-`GIT_TAG` argument.")
-
-set(GOOGLETEST_VERSION 1.10.0
-    CACHE STRING
-    "Version of googletest to use.")
-
-set(GOOGLETEST_GIT_REPOSITORY https://github.com/google/googletest.git
-    CACHE STRING
-    "URL of the git repository from which to download googletest. For more \
-details, see CMake `ExternalProject` module documentation of the \
-`GIT_REPOSITORY` argument.")
-
-set(GOOGLETEST_GIT_TAG release-${GOOGLETEST_VERSION}
-    CACHE STRING
-    "Git branch name, tag or commit hash to checkout for googletest. \
-For more details, see CMake `ExternalProject` module documentation of the \
-`GIT_TAG` argument.")
+# Version of Boost to use. It will be used as the argument to the `find_package(Boost)` call.
+overridable_variable(BOOST_VERSION 1.64)
+
+# Version of pybind11 to use.
+overridable_variable(PYBIND11_VERSION 2.5.0)
+
+# URL of the git repository from which to download pybind11. For more details, see CMake
+# `ExternalProject` module documentation of the `GIT_REPOSITORY` argument.
+overridable_variable(PYBIND11_GIT_REPOSITORY https://github.com/pybind/pybind11)
+
+# Git branch name, tag or commit hash to checkout for pybind11. For more details, see CMake
+# `ExternalProject` module documentation of the `GIT_TAG` argument.
+overridable_variable(PYBIND11_GIT_TAG v${PYBIND11_VERSION})
+
+# Version of googletest to use.
+overridable_variable(GOOGLETEST_VERSION 1.10.0)
+
+# URL of the git repository from which to download googletest. For more details, see CMake
+# `ExternalProject` module documentation of the `GIT_REPOSITORY` argument.
+overridable_variable(GOOGLETEST_GIT_REPOSITORY https://github.com/google/googletest.git)
+
+# Git branch name, tag or commit hash to checkout for googletest. For more details, see CMake
+# `ExternalProject` module documentation of the `GIT_TAG` argument.
+overridable_variable(GOOGLETEST_GIT_TAG release-${GOOGLETEST_VERSION})
 
 set(PYTHON_VERSION_STRING "" CACHE STRING "Version of Python to look for. This \
 variable can be specified by tools run directly from Python to enforce the \

cmake/set_libqi_dependency.cmake

@@ -1,22 +1,10 @@
-set(LIBQI_VERSION 1.8.6
-    CACHE STRING
-    "Version of LibQi to use. If not empty, it will be checked against the \
-version in the `package.xml` file in the libqi sources.")
+overridable_variable(LIBQI_VERSION 1.8.6)
 
 # Our github clone is sometimes late or is missing tags, so we enable
 # customisation of the URL at configuration time, so users can use another clone.
-set(LIBQI_GIT_REPOSITORY https://github.com/aldebaran/libqi.git
-    CACHE STRING
-    "URL of the git repository from which to download LibQi. For more details, \
-see CMake `ExternalProject` module documentation of the `GIT_REPOSITORY` \
-argument.")
-
-set(LIBQI_GIT_TAG qi-framework-v${LIBQI_VERSION}
-    CACHE STRING
-    "Git branch name, tag or commit hash to checkout for LibQi. \
-For more details, see CMake `ExternalProject` module documentation of the \
-`GIT_TAG` argument.")
+overridable_variable(LIBQI_GIT_REPOSITORY https://github.com/aldebaran/libqi.git)
 
+overridable_variable(LIBQI_GIT_TAG qi-framework-v${LIBQI_VERSION})
 
 if(LIBQI_VERSION)
   message(STATUS "LibQi: expected version is \"${LIBQI_VERSION}\"")

cmake/utils.cmake

@@ -83,3 +83,24 @@ function(set_install_rpath)
     endif()
   endforeach()
 endfunction()
+
+# Creates a variable that can be overridden by the user from either the
+# command-line, the cache or the environment.
+# The order of preference is:
+#   - the value from the variable in cache (or the command-line, since setting
+#   a variable from the command-line automatically adds it to the cache).
+#   - the value from the variable in the environment.
+#   - the default value for the variable.
+function(overridable_variable name default_value)
+  # The variable already exists in the cache. It's the preferred value, so we
+  # don't change it.
+  if(DEFINED CACHE{${name}})
+    return()
+  endif()
+
+  set(value ${default_value})
+  if(DEFINED ENV{${name}})
+    set(value $ENV{${name}})
+  endif()
+  set(${name} ${value} PARENT_SCOPE)
+endfunction()