Fix searching for dll paths, instead of adding .lib path. (#6410)

* Fix searching for dll paths, instead of adding .lib path.

* Remove dublicated  $.

Wrap dll search for windows in "if WIN32".

* Don't special case io_ply as it is inserted as a component earlier.

* Address suggestion from copilot.

Author: larshg

PCLConfig.cmake.in

@@ -632,21 +632,73 @@ foreach(component ${PCL_TO_FIND_COMPONENTS})
     endforeach()
     if(_is_header_only EQUAL -1)
       add_library(${pcl_component} @PCL_LIB_TYPE@ IMPORTED)
-      if(PCL_${COMPONENT}_LIBRARY_DEBUG)
-        set_target_properties(${pcl_component}
-          PROPERTIES
-            IMPORTED_CONFIGURATIONS "RELEASE;DEBUG"
-            IMPORTED_LOCATION_RELEASE "${PCL_${COMPONENT}_LIBRARY}"
-            IMPORTED_LOCATION_DEBUG "${PCL_${COMPONENT}_LIBRARY_DEBUG}"
-            IMPORTED_IMPLIB_RELEASE "${PCL_${COMPONENT}_LIBRARY}"
-            IMPORTED_IMPLIB_DEBUG "${PCL_${COMPONENT}_LIBRARY_DEBUG}"
-        )
+
+      if(WIN32 AND NOT MINGW AND PCL_SHARED_LIBS)
+        # On Windows with shared libraries, .dll (runtime) and .lib (import library)
+        # are separate artifacts.
+        # find dll paths
+        find_file(PCL_${COMPONENT}_DLL_PATH
+            NAMES
+              ${pcl_component}${PCL_RELEASE_SUFFIX}.dll
+              ${pcl_component}${PCL_RELWITHDEBINFO_SUFFIX}.dll
+              ${pcl_component}${PCL_MINSIZEREL_SUFFIX}.dll
+            HINTS "${PCL_ROOT}/bin"
+            NO_DEFAULT_PATH)
+        mark_as_advanced(PCL_${COMPONENT}_DLL_PATH)
+        find_file(PCL_${COMPONENT}_DLL_PATH_DEBUG
+              NAMES ${pcl_component}${PCL_DEBUG_SUFFIX}.dll
+              HINTS "${PCL_ROOT}/bin"
+              NO_DEFAULT_PATH)
+        mark_as_advanced(PCL_${COMPONENT}_DLL_PATH_DEBUG)
+
+        if(PCL_${COMPONENT}_LIBRARY_DEBUG)
+          set_target_properties(${pcl_component}
+            PROPERTIES
+              IMPORTED_CONFIGURATIONS "RELEASE;DEBUG"
+              IMPORTED_IMPLIB_RELEASE "${PCL_${COMPONENT}_LIBRARY}"
+              IMPORTED_IMPLIB_DEBUG "${PCL_${COMPONENT}_LIBRARY_DEBUG}"
+          )
+          if(PCL_${COMPONENT}_DLL_PATH)
+            set_target_properties(${pcl_component} PROPERTIES
+              IMPORTED_LOCATION_RELEASE "${PCL_${COMPONENT}_DLL_PATH}")
+          else()
+            pcl_message(WARNING "Could not find release DLL for ${pcl_component}. Runtime path will not be set.")
+          endif()
+          if(PCL_${COMPONENT}_DLL_PATH_DEBUG)
+            set_target_properties(${pcl_component} PROPERTIES
+              IMPORTED_LOCATION_DEBUG "${PCL_${COMPONENT}_DLL_PATH_DEBUG}")
+          else()
+            pcl_message(WARNING "Could not find debug DLL for ${pcl_component}. Runtime path will not be set.")
+          endif()
+        else()
+          set_target_properties(${pcl_component}
+            PROPERTIES
+              IMPORTED_IMPLIB "${PCL_${COMPONENT}_LIBRARY}"
+          )
+          if(PCL_${COMPONENT}_DLL_PATH)
+            set_target_properties(${pcl_component} PROPERTIES
+              IMPORTED_LOCATION "${PCL_${COMPONENT}_DLL_PATH}")
+          else()
+            pcl_message(WARNING "Could not find DLL for ${pcl_component}. Runtime path will not be set.")
+          endif()
+        endif()
       else()
-        set_target_properties(${pcl_component}
-          PROPERTIES
-            IMPORTED_LOCATION "${PCL_${COMPONENT}_LIBRARY}"
-            IMPORTED_IMPLIB "${PCL_${COMPONENT}_LIBRARY}"
-        )
+        # On Linux/macOS/MINGW, or when PCL is built as static libraries,
+        # the library file is both the link-time and runtime artifact,
+        # so IMPORTED_LOCATION is sufficient.
+        if(PCL_${COMPONENT}_LIBRARY_DEBUG)
+          set_target_properties(${pcl_component}
+            PROPERTIES
+              IMPORTED_CONFIGURATIONS "RELEASE;DEBUG"
+              IMPORTED_LOCATION_RELEASE "${PCL_${COMPONENT}_LIBRARY}"
+              IMPORTED_LOCATION_DEBUG "${PCL_${COMPONENT}_LIBRARY_DEBUG}"
+          )
+        else()
+          set_target_properties(${pcl_component}
+            PROPERTIES
+              IMPORTED_LOCATION "${PCL_${COMPONENT}_LIBRARY}"
+          )
+        endif()
       endif()
     else() # header-only
       add_library(${pcl_component} INTERFACE IMPORTED)