ProjectRed/core/build.gradle at 2b01cc07065743578cfe997bd6dc2dc271f48dd6 · MrTJP/ProjectRed · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
plugins {
    id 'net.neoforged.moddev'
}

String mod_id = 'projectred_core'

neoForge {
    version = forge_version

    accessTransformers {
        publish file("src/main/resources/META-INF/accesstransformer.cfg")
    }

    runs {
        data {
            data()
            programArguments.addAll '--mod', mod_id, '--all', '--output', file("src/main/generated").absolutePath, '--existing', file("src/main/resources").absolutePath
        }
    }

    unitTest {
        enable()
    }
}

dependencies {
    implementation "io.codechicken:CodeChickenLib:${mc_version}-${ccl_version}"
    implementation "io.codechicken:CBMultipart:${mc_version}-${cbm_version}"

    accessTransformers "io.codechicken:CodeChickenLib:${mc_version}-${ccl_version}"
    accessTransformers "io.codechicken:CBMultipart:${mc_version}-${cbm_version}"

    // ProjectRed API
    compileOnly project(":api") // Not on runtime bc already included via JarJar
    jarJar(project(":api")) // Use JarJar to bake within Core jar

    // JEI
    compileOnly("mezz.jei:jei-${mc_version}-common-api:${jei_version}")
    compileOnly("mezz.jei:jei-${mc_version}-neoforge-api:${jei_version}")
    runtimeOnly("mezz.jei:jei-${mc_version}-neoforge:${jei_version}")

    // CCTweaked
    compileOnly("cc.tweaked:cc-tweaked-${mc_version}-core-api:${cct_version}")
    compileOnly("cc.tweaked:cc-tweaked-${mc_version}-forge-api:${cct_version}")
    runtimeOnly("cc.tweaked:cc-tweaked-${mc_version}-forge:${cct_version}")

    testImplementation 'org.junit.jupiter:junit-jupiter-api:5.8.2'
    testRuntimeOnly 'org.junit.jupiter:junit-jupiter-engine:5.8.2'
}

test {
    useJUnitPlatform()
    jvmArgs('-Xmx3G', '-Xms1G')
}