frmMain.vb


Imports System.IO
Imports System.Runtime.InteropServices
Imports System.Threading
Imports IniParser

Module GlobalVariables
    Public _iniDict As Model.IniData
    Public _iniParserObj As New FileIniDataParser
    Public _ini As iniWrapper

    Public _MainFormObj As frmMain
    Public _initialized As Boolean = False
    Public _pathList As ListViewHelper
    Public _favoritesList As List(Of String)
    Public _parentPathCharCount As Integer = 0
    Public _fileNameCharCount As Integer = 0
    Public _fullPathCharCount As Integer = 0
    Public _MaxPathLength As Integer

    Public _OriginalDPI As Integer
    Public _DPI As Integer
    Public _FontName As String
    Public _FontSize As Single

    Public _lastAction As UndoData

    Public Const _MinX As Single = 11.5
    Public Const _MinY As Single = 6.5
    Public Const _sLwidth As Single = 1.25

    Public _FolderInfo As FolderSelect

    <STAThread>
    Public Sub Main() 'Required to enable High DPI mode for winforms

        Application.EnableVisualStyles()
        Application.SetCompatibleTextRenderingDefault(False)

        Application.Run(New frmMain())

    End Sub


    '___________________________________________Used for vertical centering RTB text boxes
    Public Const EM_SETRECT As Integer = &HB3
    <StructLayout(LayoutKind.Sequential)>
    Public Structure RECT
        Public Left As Integer
        Public Top As Integer
        Public Right As Integer
        Public Bottom As Integer
    End Structure

    <DllImport("user32.dll")>
    Public Function SendMessage(hWnd As IntPtr, msg As Integer, wParam As IntPtr, ByRef lParam As RECT) As IntPtr
    End Function
    '_______________________________________
    <DllImport("user32.dll")>
    Public Function SendMessage(hWnd As IntPtr, Msg As UInteger, wParam As IntPtr, lParam As IntPtr) As IntPtr
    End Function

    Public Sub CenterRTBvertically(rtb As RichTextBox)
        Dim fontHeight As Integer = TextRenderer.MeasureText("A", rtb.Font).Height
        Dim topPadding As Integer = (rtb.Height - fontHeight) \ 2

        Dim rect As New RECT() With {
            .Left = 3,
            .Top = If(topPadding > 0, topPadding, 0),
            .Right = rtb.Width - 1,
            .Bottom = rtb.Height
        }

        SendMessage(rtb.Handle, EM_SETRECT, IntPtr.Zero, rect)
    End Sub

    Public Sub AlignControlToRight(margin As Integer, ctrl As Control, frm As Form, Optional WidenTo As Boolean = False)
        If WidenTo = False Then
            ctrl.Left = frm.ClientSize.Width - ctrl.Width - margin
        Else
            ctrl.Width = frm.ClientSize.Width - margin - ctrl.Left
        End If
    End Sub
    Public Sub AlignControlToRight(margin As Integer, ctrl As Control(), frm As Form, Optional WidenTo As Boolean = False)

        If WidenTo = False Then
            Dim l1 As Integer = ctrl(0).Left
            ctrl(0).Left = frm.ClientSize.Width - ctrl(0).Width - margin
            Dim offset As Integer = ctrl(0).Left - l1
            For i As Integer = 1 To ctrl.Length - 1
                ctrl(i).Left = ctrl(i).Left + offset
            Next
        Else
            ctrl(0).Width = frm.ClientSize.Width - margin - ctrl(0).Left
        End If
    End Sub


    Public Class ToolTipCustom
        Dim TIP As New ToolTip

        Public Property DisplayLength_ms As Integer
            Get
                Return TIP.AutoPopDelay
            End Get
            Set(value As Integer)
                TIP.AutoPopDelay = DisplayLength_ms
            End Set
        End Property

        Sub New()
            TIP.AutoPopDelay = 10000
            TIP.InitialDelay = 150
            TIP.ReshowDelay = 100

        End Sub

        Sub Add(ctrl As Control, captionText As String)
            TIP.SetToolTip(ctrl, captionText)
        End Sub

        Sub AddWorkAround(ctrl As Control, captionText As String)
            AddHandler ctrl.MouseHover, Sub() TIP.SetToolTip(ctrl, captionText)

        End Sub

    End Class
End Module



Public Class frmMain
    Private _CurrentLVitem As ListViewItem
    Private _StatusLabel_Main As New ToolStripStatusLabel
    Private _StatusLabel_FileCount As New ToolStripStatusLabel
    Private _rtbHelpBox As New RichTextBox

    Private _ToolTips As New ToolTipCustom
    Private _ConfirmChangeOnEnter As Boolean

    Private cts As CancellationTokenSource

    Private _hook As ListViewHook

    '________________________________________________Allows auto expanding the windows when double clicking the right edge
    Private Const WM_NCLBUTTONDBLCLK As Integer = &HA3
    Private Const HTRIGHT As Integer = 11       ' Right edge
    Private Const HTSIZEBOX As Integer = 4      ' Bottom-right corner (if needed)
    Protected Overrides Sub WndProc(ByRef m As Message)
        If m.Msg = WM_NCLBUTTONDBLCLK Then
            Dim hitTest As Integer = m.WParam.ToInt32()

            If hitTest = HTRIGHT Then
                '
                ExtendWindow()
                Return ' Optionally suppress default behavior (e.g., resizing)
            End If
        End If

        MyBase.WndProc(m)
    End Sub
    '___________________________________________________


    <Runtime.InteropServices.DllImport("user32.dll")>
    Private Shared Function GetDpiForWindow(hwnd As IntPtr) As UInteger
    End Function
    Protected Overrides Sub OnDpiChanged(e As DpiChangedEventArgs)
        MyBase.OnDpiChanged(e)

        DPIrescale()
    End Sub

    Private Sub DPIrescale() 'Certain dimensional parameters require manual correction upon DPI change
        _DPI = Me.DeviceDpi

        Me.MinimumSize = New Size(_MinX * _DPI, _MinY * _DPI)
        Me.StatusStripMain.Items(2).Size = New Size(_sLwidth * _DPI, 26)
        _pathList.UpdateColumnsFromDPIchange(_DPI)

        rtbOriginalName.Font = Nothing 'workaround for winforms rendering bug

        Dim correctedFontSize As Single = (_DPI / _OriginalDPI) * _FontSize 'Rich text box scaling is stupid and this is a workaround
        rtbOriginalName.Font = New Font(_FontName, correctedFontSize, FontStyle.Regular)

        CenterRTBvertically(rtbOriginalName)

    End Sub
    Public Sub FixControlScale(ctrl As Control, sX As Single, Optional fontSpec As Font = Nothing, Optional changeSize As Boolean = True)

        ctrl.Top = ctrl.Top * sX
        ctrl.Left = ctrl.Left * sX

        Dim typeStr As String = ctrl.GetType.ToString.Replace("System.Windows.Forms.", "")

        If changeSize = True Then
            Select Case typeStr
                Case "Button", "RichTextBox"
                    ctrl.Size = New Size(ctrl.Width * sX, ctrl.Height * sX)
                Case "TextBox", "ComboBox"
                    ctrl.Width = ctrl.Width * sX
                Case "Label", "CheckBox", "LinkLabel"
                Case Else
                    Stop

            End Select
        End If

        If fontSpec IsNot Nothing Then
            ctrl.Font = fontSpec
        End If

    End Sub


    Private Class ListViewHook
        Inherits NativeWindow

        Private Const WM_NOTIFY As Integer = &H4E
        Private Const HDN_FIRST As Integer = -300
        Private Const HDN_DIVIDERDBLCLICKA As Integer = HDN_FIRST - 5
        Private Const HDN_DIVIDERDBLCLICKW As Integer = HDN_FIRST - 25

        <StructLayout(LayoutKind.Sequential)>
        Private Structure NMHDR
            Public hwndFrom As IntPtr
            Public idFrom As IntPtr
            Public code As Integer
        End Structure

        <StructLayout(LayoutKind.Sequential)>
        Private Structure NMHEADER
            Public hdr As NMHDR
            Public iItem As Integer   ' Zero-based column index that was double clicked
            Public iButton As Integer
            Public pItem As IntPtr
        End Structure

        Public Sub New(lv As ListView)
            AssignHandle(lv.Handle)
        End Sub

        Protected Overrides Sub WndProc(ByRef m As Message)
            If m.Msg = WM_NOTIFY Then
                Dim nmhdr As NMHDR = DirectCast(Marshal.PtrToStructure(m.LParam, GetType(NMHDR)), NMHDR)

                If nmhdr.code = HDN_DIVIDERDBLCLICKA OrElse nmhdr.code = HDN_DIVIDERDBLCLICKW Then
                    Dim nmheader As NMHEADER = DirectCast(Marshal.PtrToStructure(m.LParam, GetType(NMHEADER)), NMHEADER)
                    Dim columnIndex As Integer = nmheader.iItem

                    _pathList.ExpandColumnToFitContents(columnIndex)
                    Return
                End If
            End If

            MyBase.WndProc(m)
        End Sub

    End Class
    Private Sub ExtendWindow()
        Dim sX As Single = _DPI / _OriginalDPI 'Apparently TextRenderer is not affected by DPI change events and so it has to be corrected for. 
        Dim curFont As New Font(_FontName, _FontSize)

        Dim p1 As Integer = rtbOriginalName.Left + TextRenderer.MeasureText(rtbOriginalName.Text, curFont).Width

        Dim columnStart As Integer = (lvMain.Left + lvMain.Columns(0).Width + lvMain.Columns(1).Width) / sX

        For i As Integer = 0 To lvMain.Items.Count - 1
            Dim p As Integer = TextRenderer.MeasureText(_pathList.GetCellEntry(i, "Path"), curFont).Width + columnStart '

            If p > p1 Then
                p1 = p
            End If
        Next

        Me.Width = p1 * sX + 36

    End Sub

    Public Sub New()
        AutoScaleMode = AutoScaleMode.None 'Extremely important to have it set to none before InitializeComponent is run
        InitializeComponent()

        Dim primScreen As Screen = Screen.PrimaryScreen
        Me.StartPosition = FormStartPosition.Manual
        Me.Location = New Point(
        primScreen.WorkingArea.Left + (primScreen.WorkingArea.Width - Me.Width) \ 2,
        primScreen.WorkingArea.Top + (primScreen.WorkingArea.Height - Me.Height) \ 2
    )

        _MainFormObj = Me
        Try
            _ini = New iniWrapper(iniPath:="\resources\User Options.ini", AutoGenerateIfMissing:=True)
        Catch ex As Exception
            MsgBox($"Settings file data is missing from \resources folder.{vbCrLf}Re-extract utility if necessary.", MsgBoxStyle.Critical, "ERROR")
            End
        End Try

        _hook = New ListViewHook(lvMain)

        'Me.AutoScaleMode = AutoScaleMode.Dpi
        _DPI = Me.DeviceDpi
        _OriginalDPI = _DPI
    End Sub


    Private Async Sub frmMain_Load(sender As Object, e As EventArgs) Handles Me.Load

        Me.Icon = My.Resources.icon

        Dim sX As Single = _DPI / 96 'scaling Factor

        Dim defaultFont As New Font("Microsoft Sans Seriff", 8.25)

        FixControlScale(tbNewName, sX,, False)
        FixControlScale(lab_SearchFolder, sX)
        FixControlScale(lab_Name, sX, defaultFont) 'default fonts don't get autoscaled apparently
        FixControlScale(lab_Total, sX, defaultFont)
        FixControlScale(lab_SelectFolder, sX)
        FixControlScale(lblMaxPathLength, sX)
        FixControlScale(lblCharCountNewName, sX)
        FixControlScale(lblCharCountNewName2, sX)
        FixControlScale(lblCharCountOriginalName, sX)
        FixControlScale(lblCharCountOriginalName2, sX)

        FixControlScale(btnCancelScan, sX, defaultFont)
        FixControlScale(btnChangeFileName, sX, defaultFont)
        FixControlScale(btnChangeFolderName, sX, defaultFont)
        FixControlScale(btnUndo, sX, defaultFont)
        FixControlScale(btnOptions, sX, defaultFont)
        FixControlScale(btnSelectFolder, sX, defaultFont)
        FixControlScale(btnFavoriteFolder, sX, defaultFont)
        FixControlScale(btnUnfavoriteFolder, sX, defaultFont)
        FixControlScale(btnScanFolder, sX, defaultFont)
        FixControlScale(btnLeftFolder, sX)
        FixControlScale(btnRightFolder, sX)

        FixControlScale(cbShowHelp, sX) : cbShowHelp.Width = cbShowHelp.Width * sX : cbShowHelp.Height = cbShowHelp.Height * sX
        FixControlScale(cbSearchSubfolders, sX, defaultFont)
        FixControlScale(tbSearchFolder, sX)
        FixControlScale(tbMaxPathLength, sX, defaultFont)
        FixControlScale(rtbOriginalName, sX)
        FixControlScale(cmbBoxFavorites, sX)


        With Me
            Dim winSize As New Size(_MinX * _DPI, _MinY * _DPI)
            .Size = winSize
            .MinimumSize = winSize
        End With

        Dim LeftMargin As Integer = 8 * sX
        Dim RightMargin As Integer = 8 * sX

        AlignControlToRight(RightMargin, {tbMaxPathLength, lblMaxPathLength}, Me)
        AlignControlToRight(RightMargin, tbNewName, Me, True)
        AlignControlToRight(RightMargin, rtbOriginalName, Me, True)
        AlignControlToRight(RightMargin, {cbShowHelp, btnOptions}, Me)


        btnScanFolder.Left = LeftMargin
        tbSearchFolder.Left = LeftMargin
        lab_SearchFolder.Left = LeftMargin

        btnCancelScan.Hide()
        btnCancelScan.Location = btnScanFolder.Location
        btnUnfavoriteFolder.Hide()
        btnUnfavoriteFolder.Location = btnFavoriteFolder.Location
        btnChangeFolderName.Hide()
        btnChangeFolderName.Location = btnChangeFileName.Location


        Me.Controls.Add(_rtbHelpBox)
        With _rtbHelpBox
            .ReadOnly = True
            .BackColor = SystemColors.ControlLightLight
            .Margin = New Padding(16)
            .Dock = DockStyle.None
            .Left = LeftMargin - 1
            .Width = Me.ClientSize.Width - LeftMargin - RightMargin + 4 * sX
            .Top = cbShowHelp.Bottom + 4 * sX
            .Height = Me.ClientSize.Height - .Top - StatusStripMain.Height - 2 * sX
            .Anchor = AnchorStyles.Left Or AnchorStyles.Right Or AnchorStyles.Bottom Or AnchorStyles.Top
            .BringToFront()
            .Hide()
        End With

        Dim statusBarHeight As Single = 24
        With StatusStripMain
            _StatusLabel_Main.Name = "statusLabel_Main"
            _StatusLabel_Main.AutoSize = False
            _StatusLabel_Main.Size = New Size(400 * sX, statusBarHeight * sX)
            _StatusLabel_Main.Text = "Ready"

            _StatusLabel_Main.TextAlign = ContentAlignment.MiddleLeft
            _StatusLabel_Main.Alignment = ToolStripItemAlignment.Right
            _StatusLabel_Main.Margin = New Padding(6 * sX, 0, 0, 0)

            _StatusLabel_FileCount.Name = "statusLabel_FileCount"
            _StatusLabel_FileCount.Size = New Size(_sLwidth * _DPI, statusBarHeight * sX)
            _StatusLabel_FileCount.AutoSize = False
            _StatusLabel_FileCount.Text = "Files Found: "
            _StatusLabel_FileCount.TextAlign = ContentAlignment.MiddleLeft
            _StatusLabel_FileCount.Alignment = ToolStripItemAlignment.Right
            _StatusLabel_FileCount.Margin = New Padding(0, 0, 6 * sX, 0)

            Dim emptyStatusLabel As New ToolStripStatusLabel()
            emptyStatusLabel.Text = String.Empty
            emptyStatusLabel.Spring = True

            .Items.Add(_StatusLabel_Main)
            .Items.Add(emptyStatusLabel)
            .Items.Add(_StatusLabel_FileCount)
            .Height = statusBarHeight * sX
            '.AutoSize = False
        End With

        With lvMain
            .CheckBoxes = False
            .FullRowSelect = True
            .AllowColumnReorder = False
            .MultiSelect = False
            .View = View.Details

            .Top = .Top * sX
            .Left = LeftMargin
            .Width = Me.ClientSize.Width - LeftMargin - RightMargin
            .Height = Me.ClientSize.Height - .Top - StatusStripMain.Height - 6 * sX

            .Anchor = AnchorStyles.Left Or AnchorStyles.Right Or AnchorStyles.Bottom Or AnchorStyles.Top

            .Columns.Add("Path Length", 65, HorizontalAlignment.Left)
            .Columns.Add("Name Length", 65, HorizontalAlignment.Left)
            .Columns.Add("Path", 1500, HorizontalAlignment.Left)
        End With


        With cmbBoxFavorites
            Dim favArr() As String = _ini.GetIterativeEntryArray("FavFolder", "FavoriteFolders")
            .Items.Add("Favorite Folders")

            _favoritesList = New List(Of String)(favArr)
            If favArr.Length <> 0 Then
                For i As Integer = 0 To favArr.Length - 1
                    .Items.Add(favArr(i))
                Next
            End If
            .SelectedIndex = 0
            .DropDownStyle = ComboBoxStyle.DropDownList
            .DrawMode = DrawMode.OwnerDrawFixed

        End With

        _pathList = New ListViewHelper(lvMain, _ini.Entry("DefaultTableConfig"), True)
        _pathList.ApplyConfig(_ini.Entry("TableConfig"))
        _pathList.AddContextMenuFunction("Show in file explorer", AddressOf ShowInExplorer, "Path")
        _pathList.AddContextMenuFunction("Save view", AddressOf SaveTableView)


        _ConfirmChangeOnEnter = _ini.Entry("ConfirmChangeOnEnter")
        cbSearchSubfolders.Checked = _ini.Entry("IncludeSubFolders")

        tbNewName.Anchor = AnchorStyles.Left Or AnchorStyles.Top Or AnchorStyles.Right

        With rtbOriginalName
            .ReadOnly = True
            .BackColor = Color.FromArgb(248, 248, 248)
            .Cursor = Cursors.Arrow
            .Anchor = AnchorStyles.Left Or AnchorStyles.Top Or AnchorStyles.Right
            .BorderStyle = BorderStyle.None
            .Multiline = False

            'AlignRightEdgeOfControl(rtbOriginalName, lvMain)
        End With

        tbSearchFolder.Text = _ini.Entry("LastSelectedFolder")
        tbMaxPathLength.Text = _ini.Entry("MaxPathLength")
        tbMaxPathLength.TextAlign = HorizontalAlignment.Right

        _ToolTips.Add(tbMaxPathLength, "The max file path length in Windows is effectively 259 characters. Though technically it's 260 when including the null terminator of a string.")
        _ToolTips.Add(lblMaxPathLength, "The max file path length in Windows is effectively 259 characters. Though technically it's 260 when including the null terminator of a string.")
        _ToolTips.Add(lblCharCountOriginalName, "Left number is the total path length. Right number is the current name length.")
        _ToolTips.Add(lblCharCountNewName, "Left number is the total path length. Right number is the current name length.")
        _ToolTips.Add(lblCharCountOriginalName2, "Left number is the total path length. Right number is the current name length.")
        _ToolTips.Add(lblCharCountNewName2, "Left number is the total path length. Right number is the current name length.")
        _ToolTips.Add(btnUndo, "You can only undo one change.")


        Dim adjustedFont As Font
        Try
            _FontSize = _ini.Entry("FontSize")
            _FontName = _ini.Entry("FontName")

            Dim installedFont As FontFamily = FontFamily.Families.FirstOrDefault(Function(f) f.Name.Equals(_FontName, StringComparison.OrdinalIgnoreCase))

            If installedFont Is Nothing Then
                adjustedFont = New Font("Microsoft Sans Serif", _FontSize, FontStyle.Regular)
            End If
            adjustedFont = New Font(_FontName, _FontSize, FontStyle.Regular)

            cmbBoxFavorites.Font = adjustedFont
            lvMain.Font = adjustedFont
            tbSearchFolder.Font = adjustedFont
            tbMaxPathLength.Font = adjustedFont
            rtbOriginalName.Font = adjustedFont
            tbNewName.Font = adjustedFont
            lblCharCountNewName.Font = adjustedFont
            lblCharCountNewName2.Font = adjustedFont
            lblCharCountOriginalName.Font = adjustedFont
            lblCharCountOriginalName2.Font = adjustedFont

        Catch ex As Exception
            SetStatus("Font could not be changed.")
        End Try

        CenterRTBvertically(rtbOriginalName)

        btnScanFolder.Focus()
        tbMaxPathLength.TabIndex = 39
        btnSelectFolder.TabIndex = 40
        btnScanFolder.TabIndex = 41

        tbNewName.TabIndex = 50
        btnChangeFileName.TabIndex = 51
        btnChangeFolderName.TabIndex = 51


        Me.Text = "LongPathFixer v1.0 - Long file path search and rename"

        If _ini.Entry("Start11TaskBarFix") = True Then
            Me.WindowState = FormWindowState.Minimized
            Me.WindowState = FormWindowState.Normal
        End If


        _initialized = True

    End Sub

    Public Sub SaveTableView()
        Try
            _ini.Entry("TableConfig") = _pathList.GetConfigStr()
            SetStatus("Table view saved")
        Catch ex As Exception
            SetStatus("Error saving table view")
        End Try
    End Sub

    Public Sub SetStatus(statusStr As String, Optional mode As String = "[main,count]", Optional flashStatus As Boolean = False)

        Dim StatusLabel As ToolStripStatusLabel
        Select Case mode
            Case "[main,count]", "main"
                StatusLabel = _StatusLabel_Main
            Case "count"
                statusStr = "Files Found: " & statusStr
                StatusLabel = _StatusLabel_FileCount
            Case Else
                Stop
        End Select

        If _StatusStripMain.InvokeRequired = True Then
            _StatusStripMain.Invoke(Sub() StatusLabel.Text = statusStr)
        Else
            StatusLabel.Text = statusStr
        End If
        Application.DoEvents() 'UI doesn't always refresh without this command

        If flashStatus = True Then
            Dim black As Color = Color.Black
            Dim red As Color = Color.Red

            Dim act As Action = Sub()
                                    For i = 0 To 5
                                        _StatusStripMain.Invoke(Sub() StatusLabel.ForeColor = red)
                                        Task.Delay(100).Wait()
                                        _StatusStripMain.Invoke(Sub() StatusLabel.ForeColor = black)
                                        Task.Delay(100).Wait()
                                    Next

                                End Sub


            Task.Run(act)

        End If

    End Sub

    Private Sub btnSelectFolder_Click(sender As Object, e As EventArgs) Handles btnSelectFolder.Click
        Using dialog As New WindowsAPICodePack.Dialogs.CommonOpenFileDialog()
            dialog.IsFolderPicker = True
            dialog.Title = "Select a Folder"

            If dialog.ShowDialog() = WindowsAPICodePack.Dialogs.CommonFileDialogResult.Ok Then
                tbSearchFolder.Text = dialog.FileName
            End If
        End Using

        _ini.Entry("LastSelectedFolder") = tbSearchFolder.Text
    End Sub

    Private Sub btn_Options_Click(sender As Object, e As EventArgs) Handles btnOptions.Click
        '_ini.OpenINI()
        Dim optMenu As New frmOptions(_DPI)
        optMenu.ShowDialog(Me)
    End Sub

    Private Sub btnScanFolder_Click(sender As Object, e As EventArgs) Handles btnScanFolder.Click
        _pathList.ResetColumnSort()
        btnScanFolder.Hide()
        btnCancelScan.Show()
        cts = New CancellationTokenSource()
        ScanFolder(cts)
        _lastAction.newList = True
        _ini.Entry("TableConfig") = _pathList.GetConfigStr
        _ini.Entry("MaxPathLength") = Me.tbMaxPathLength.Text
        _FolderInfo = Nothing
    End Sub


    Private Sub btnCancelScan_Click(sender As Object, e As EventArgs) Handles btnCancelScan.Click
        btnScanFolder.Show()
        btnCancelScan.Hide()
        cts.Cancel()
    End Sub

    Private Async Sub ScanFolder(cts As CancellationTokenSource)
        Dim folderPath As String = tbSearchFolder.Text
        Dim result As Boolean, maxPathLength As Integer
        result = Integer.TryParse(tbMaxPathLength.Text, maxPathLength)

        If result = False Or maxPathLength < 0 Or maxPathLength > 32767 Then
            MessageBoxCustom.Show(Me, "Max path length value Is invalid.", "Error", MessageBoxButtons.OK, MessageBoxIcon.Warning, _DPI, "beep")
            GoTo EndScan
        End If
        If IO.Directory.Exists(folderPath) = False Then
            MessageBoxCustom.Show(Me, "Given folder does Not exist.", "Error", MessageBoxButtons.OK, MessageBoxIcon.Error, _DPI, "beep")
            GoTo EndScan
        End If
        _ini.Entry("LastSelectedFolder") = folderPath
        SetStatus("Scan Started")

        _MaxPathLength = maxPathLength
        rtbOriginalName.Clear()
        tbNewName.Clear()
        lblCharCountNewName.Text = "0000"
        lblCharCountNewName2.Text = "0000"
        lblCharCountOriginalName.Text = "0000"
        lblCharCountOriginalName2.Text = "0000"
        Dim searchSubFolders As Boolean = cbSearchSubfolders.Checked

        Dim completePathArr() As String, fileList() As String, searchExceptionList As New List(Of Exception)
        Dim FilesScannedCount As Integer = 0


        Try
            Task.Run(Sub() ShowFileScanProgress(FilesScannedCount, cts.Token), cts.Token)

            fileList = Await Task.Run(Function()
                                          Return GetLongFilePaths3(folderPath, searchSubFolders, maxPathLength, completePathArr, FilesScannedCount, cts.Token, searchExceptionList)
                                      End Function, cts.Token)
            cts.Cancel()

        Catch ex As Exception
            MessageBoxCustom.Show(Me, $"UNKNOWN ERROR:{vbCrLf}{ex.Message}", "Error", MessageBoxButtons.OK, MessageBoxIcon.Error, _DPI, "error")
        End Try

        'MessageBoxCustom.Show(Me, $"File scan error occurred:{vbCrLf}{ex.InnerException.Message}", "Error", MessageBoxButtons.OK, MessageBoxIcon.Error, _DPI, "error")

        ListFiles(fileList)

        If searchExceptionList.Count = 0 Then
            SetStatus($"Searched Files: {FilesScannedCount}")
        Else
            Dim exStr As String = ""
            For Each ex As Exception In searchExceptionList
                exStr &= ex.Message & vbCrLf
            Next
            WriteToTextFile("ScanErrorLog.txt", exStr)
            SetStatus($"Searched Files: {FilesScannedCount} See ScanErrorLog for blocked folders.")
        End If


EndScan:
        btnScanFolder.Show()
        btnCancelScan.Hide()
    End Sub


    Sub ShowFileScanProgress(ByRef FilesScannedCount As Integer, token As CancellationToken)
        Try
            Do While True
                Thread.Sleep(500)
                token.ThrowIfCancellationRequested()
                SetStatus("Searched Files: " & FilesScannedCount)
            Loop
        Catch ex As Exception
            If TypeOf ex IsNot OperationCanceledException Then
                Stop
            End If
        End Try

    End Sub

    Private Sub ListFiles(pathArr() As String)

        If pathArr.Length = 0 Then
            MessageBoxCustom.Show(Me, "No file paths greater than " & _MaxPathLength & " characters found.", "Search Result", MessageBoxButtons.OK, MessageBoxIcon.Asterisk, _DPI, "notifyAlt")
            SetStatus("0", "count")
            Exit Sub
        End If

        SetStatus(pathArr.Length + 1, "count")

        lvMain.BeginUpdate()
        _pathList.ClearEntries()

        With _pathList
            For Each str As String In pathArr
                .AddRow()
                .SetCellVal(str, "Path")
                .SetCellVal(str.Length, "Path Length")
                .SetCellVal(Path.GetFileName(str).Length, "Name Length")

            Next
        End With

        lvMain.EndUpdate()
    End Sub

    Private Sub cbSearchSubfolders_CheckedChanged(sender As Object, e As EventArgs) Handles cbSearchSubfolders.CheckedChanged
        If _initialized = True Then
            _ini.Entry("IncludeSubFolders") = cbSearchSubfolders.Checked
        End If
    End Sub


    Private Sub btnUndo_Click(sender As Object, e As EventArgs) Handles btnUndo.Click

        If _lastAction.newName <> "" Then
            If _lastAction.mode = "file" Then
                If _lastAction.newList = False Then

                    Dim fileFound As Boolean = False
                    For Each lvItem As ListViewItem In lvMain.Items
                        If lvItem.SubItems(2).Text = _lastAction.newPath Then
                            lvItem.Selected = True
                            tbNewName.Text = _lastAction.OriginalName
                            fileFound = True
                            Exit For
                        End If
                    Next

                    If fileFound = True Then
                        Dim result As String = ChangeFileOrFolderName("file")
                        If result.StartsWith("success") = False Then
                            SetStatus("UNDO FAILED")

                        Else
                            SetStatus("Undo Name Change Successful",, True)
                            _lastAction = Nothing
                        End If
                    Else
                        AskUndo("file")
                    End If

                Else
                    AskUndo("file")
                End If

            Else 'if mode = "folder" then
                Dim aFullPath As String = ""
                If _lastAction.newList = False Then
                    For Each lvItem As ListViewItem In lvMain.Items
                        If lvItem.SubItems(2).Text.StartsWith(_lastAction.newPath) = True Then
                            aFullPath = lvItem.SubItems(2).Text
                            lvItem.Selected = True
                            Exit For
                        End If
                    Next

                    _FolderInfo = Nothing
                    _FolderInfo = New FolderSelect(aFullPath)

                    For i As Integer = 0 To _FolderInfo.FolderArr.Length - 1
                        If _FolderInfo.CurrentFolder("fullPath") = _lastAction.newPath Then
                            Exit For
                        End If
                        FolderSelectionMode("left")
                    Next

                    If _FolderInfo.CurrentFolder("fullPath") = _lastAction.newPath Then
                        tbNewName.Text = _lastAction.OriginalName
                        Dim result As String = ChangeFileOrFolderName("folder")

                        If result.StartsWith("success") = False Then
                            SetStatus("UNDO FAILED")
                        Else
                            SetStatus("Undo Name Change Successful",, True)
                            _lastAction = Nothing
                        End If
                    Else
                        AskUndo("folder")
                    End If

                Else
                    AskUndo("folder")
                End If
            End If
        Else
            MessageBoxCustom.Show(Me, "Nothing to undo", "Undo", MessageBoxButtons.OK, MessageBoxIcon.Exclamation, _DPI, "beep")
        End If


    End Sub

    Private Sub AskUndo(mode As String)
        If vbYes = MessageBoxCustom.Show(Me, $"Change the following?{vbCrLf}{_lastAction.newPath}{vbCrLf}{vbCrLf}to{vbCrLf}{vbCrLf}{_lastAction.OriginalPath}", "Undo Confirmation", MessageBoxButtons.YesNo, MessageBoxIcon.Question, _DPI, "notifyAlt",, 800) Then
            Dim folderMode As Boolean = If(mode = "file", False, True)

            Dim result As String = ChangeFileName(_lastAction.newPath, _lastAction.OriginalName, folderMode)
            If result.StartsWith("success") = True Then
                SetStatus("Undo Name Change Successful",, True)
                _lastAction = Nothing
            Else
                MessageBoxCustom.Show(Me, $"Failed to undo name change. Could not change{vbCrLf}{_lastAction.newPath}{vbCrLf}{vbCrLf}to{vbCrLf}{vbCrLf}{_lastAction.OriginalPath}", "Undo Error", MessageBoxButtons.OK, MessageBoxIcon.Error, _DPI, "criticalStop",, 800)
            End If

        End If

    End Sub

    Private Sub btnChangeFileName_Click(sender As Object, e As EventArgs) Handles btnChangeFileName.Click
        ChangeFileOrFolderName("file")

    End Sub

    Private Sub btnChangeFolderName_Click(sender As Object, e As EventArgs) Handles btnChangeFolderName.Click
        ChangeFileOrFolderName("folder")
    End Sub

    Private Function ChangeFileOrFolderName(Optional mode As String = "[file,folder]") As String
        Dim fullPath As String, result As String, folderMode As Boolean

        Try
            If mode = "file" Then
                fullPath = _pathList.GetCellEntry(_CurrentLVitem, "Path")
                folderMode = False
            ElseIf mode = "folder" Then
                fullPath = _FolderInfo.CurrentFolder("fullPath")
                folderMode = True
            Else
                Stop
                Return ""
            End If
        Catch ex As Exception
            Return ""
        End Try

        result = ChangeFileName(fullPath, tbNewName.Text, folderMode)

        If result.StartsWith("success") = False Then '
            MessageBoxCustom.Show(Me, $"Error changing {mode} name." & vbCrLf & result, "Error", MessageBoxButtons.OK, MessageBoxIcon.Error, _DPI, "beep")
            SetStatus($"ERROR: {mode} name not changed")

        Else 'success
            _lastAction.newName = tbNewName.Text
            _lastAction.OriginalPath = fullPath
            _lastAction.mode = mode
            _lastAction.newList = False

            If mode = "file" Then
                Dim newPath As String = Path.GetDirectoryName(fullPath) & "\" & tbNewName.Text
                Dim NameLength As Integer = tbNewName.Text.Length
                Dim PathLength As Integer = newPath.Length
                _pathList.SetCellVal2(NameLength, "Name Length", _CurrentLVitem)
                _pathList.SetCellVal2(PathLength, "Path Length", _CurrentLVitem)
                _pathList.SetCellVal2(newPath, "Path", _CurrentLVitem)

                If PathLength < _MaxPathLength Then
                    _pathList.SetBackColor(Color.FromArgb(255, 255, 190), "AllColumns", _CurrentLVitem)
                End If

            Else 'if mode = "folder"

                Dim currentPath As String = _FolderInfo.CurrentFolder("fullPath") ' current path of the folder to be renamed
                Dim newPath As String = _FolderInfo.CurrentFolder("parentFolder") & "\" & tbNewName.Text 'new path name for folder being renamed

                For i As Integer = 0 To _pathList.RowCount - 1
                    Dim pathStr As String = _pathList.GetCellEntry(i, "Path") 'filename for row
                    If pathStr.StartsWith(currentPath) = True Then
                        fullPath = _pathList.GetCellEntry(i, "Path")
                        Dim newFullPath As String = $"{newPath}{fullPath.Substring(currentPath.Length)}" 'new file path for the row

                        _pathList.SetCellVal(newFullPath.Length, "Path Length", i)
                        _pathList.SetCellVal(newFullPath, "Path", i)

                        If newFullPath.Length <= _MaxPathLength Then
                            _pathList.SetBackColor(Color.FromArgb(255, 255, 190), "AllColumns", i)
                        End If
                    End If
                Next
            End If

            If result.Contains("cmdMove") Then
                SetStatus($"F{mode.Substring(1)} name changed successfully. cmd.exe MOVE was used")
            Else
                SetStatus($"F{mode.Substring(1)} name changed successfully")
            End If

            _FolderInfo = Nothing
        End If

        Return result
    End Function

    Private Sub tbNewName_KeyDown(sender As Object, e As KeyEventArgs) Handles tbNewName.KeyDown
        If e.KeyCode = Keys.Enter Then
            e.SuppressKeyPress = True ' Prevent ding sound

            Dim question As String, resp As Integer, subR As Action(Of Object, EventArgs)
            If _FolderInfo.initialized = False Then 'if False, then folder select mode should be 
                question = "Are you sure you want to change this file name?"
                subR = AddressOf btnChangeFileName_Click
            Else
                question = "Are you sure you want to change this folder name?"
                subR = AddressOf btnChangeFolderName_Click
            End If

            If rtbOriginalName.Text = "" Then
                'do nothing
            ElseIf _ConfirmChangeOnEnter = True Then
                resp = MessageBoxCustom.Show(Me, question, "Change Confirmation", MessageBoxButtons.YesNo, MessageBoxIcon.Question, _DPI)
            Else
                resp = vbYes
            End If

            If resp = vbYes Then
                subR(New Object, New EventArgs)
            End If
        End If
    End Sub

    Private Sub btnRightLeftFolder_Click(sender As Windows.Forms.Button, e As EventArgs) Handles btnRightFolder.Click, btnLeftFolder.Click
        If sender.Name = "btnLeftFolder" Then
            FolderSelectionMode("left")
        Else
            FolderSelectionMode("right")
        End If

    End Sub

    Private Sub FolderSelectionMode(Optional mode As String = "[left,right]")
        Dim folderName As String
        If _FolderInfo.initialized = False Then

            Try
                Dim path As String = _pathList.GetCellEntry(_CurrentLVitem, "Path")
                _FolderInfo = New FolderSelect(path)
            Catch ex As Exception
                Exit Sub
            End Try

            folderName = _FolderInfo.CurrentFolder


            Dim arr() As String = _FolderInfo.FolderArr
            WriteToOriginalNameBox(rtbOriginalName, arr)

            btnChangeFileName.Hide()
            btnChangeFolderName.Show()
        Else

            Select Case mode
                Case "left"
                    folderName = _FolderInfo.SwitchFolder("up")
                Case "right"
                    folderName = _FolderInfo.SwitchFolder("down")
                Case Else
                    Stop
                    Return
            End Select

            WriteToOriginalNameBox(rtbOriginalName, _FolderInfo.FolderArr)
        End If
        _parentPathCharCount = _fullPathCharCount - folderName.Length
        tbNewName.Text = folderName
        lblCharCountOriginalName2.Text = CStr(folderName.Length).PadLeft(4, " ")

    End Sub

    Private Sub WriteToOriginalNameBox(rtb As RichTextBox, arr() As String)
        rtbOriginalName.Clear()

        For i As Integer = 0 To arr.Length - 1
            If i <> _FolderInfo.CurrentIndex Then
                rtbOriginalName.AppendText(arr(i) & "\")
            Else
                Dim c As Integer = rtbOriginalName.TextLength
                rtbOriginalName.AppendText(arr(i) & "\")
                rtbOriginalName.Select(c, arr(i).Length)
                'rtbOriginalName.SelectionFont = New Font(_FontName, _FontSize, FontStyle.Bold)
                rtbOriginalName.SelectionBackColor = Color.FromArgb(255, 255, 200)
            End If
        Next
        rtbOriginalName.ReadOnly = False
        rtbOriginalName.Select(rtbOriginalName.TextLength - 1, 1)
        rtbOriginalName.SelectedText = ""
        rtbOriginalName.ReadOnly = True
    End Sub


    Private Sub btnFavoriteFolder_Click(sender As Object, e As EventArgs) Handles btnFavoriteFolder.Click
        Dim iniVal As String = Me.tbSearchFolder.Text

        If iniVal = "" Then
            MessageBoxCustom.Show(Me, "Error: No search folder provided.", "ERROR", MessageBoxButtons.OK, MessageBoxIcon.Hand, _DPI, "beep")
            Return
        End If

        If _favoritesList.Contains(iniVal) = False Then
            _favoritesList.Add(iniVal)
            _ini.AddIterativeEntry("FavFolder", iniVal, "FavoriteFolders")

            Me.cmbBoxFavorites.Items.Add(iniVal)
            Me.cmbBoxFavorites.Text = iniVal
            SetStatus("Folder has been saved to favorites")
        Else
            SetStatus("Folder already in favorites")
        End If

    End Sub
    Private Sub btnUnfavoriteFolder_Click(sender As Object, e As EventArgs) Handles btnUnfavoriteFolder.Click
        Dim favPath As String = cmbBoxFavorites.Text

        If _ini.RemoveEntryByVal(favPath, "FavoriteFolders") = True Then
            cmbBoxFavorites.Items.Remove(cmbBoxFavorites.SelectedItem)
            cmbBoxFavorites.SelectedIndex = 0
            _favoritesList.Remove(favPath)

            _ini.ResetKeyPairList("FavFolder", "FavoriteFolders", _favoritesList)

            btnUnfavoriteFolder.Hide()
            btnFavoriteFolder.Show()
            SetStatus("Folder removed from favorites")
        Else
            SetStatus("Error removing from favorites occurred")
        End If

    End Sub

    Private Sub cmbBoxFavorites_TextChanged(sender As Object, e As EventArgs) Handles cmbBoxFavorites.TextChanged
        If _initialized = True Then
            If cmbBoxFavorites.SelectedItem <> "Favorite Folders" Then
                _initialized = False
                tbSearchFolder.Text = cmbBoxFavorites.Text

                btnUnfavoriteFolder.Show()
                btnFavoriteFolder.Hide()
                _initialized = True
            Else
                btnUnfavoriteFolder.Hide()
                btnFavoriteFolder.Show()
            End If
        End If
    End Sub
    Private Sub cmbBoxFavorites_DrawItem(sender As Object, e As DrawItemEventArgs) Handles cmbBoxFavorites.DrawItem
        If e.Index < 0 Then Return

        e.DrawBackground()

        Dim itemText As String = cmbBoxFavorites.Items(e.Index).ToString()

        ' Define right-aligned string format
        Dim sf As New StringFormat()
        sf.Alignment = StringAlignment.Far  ' Far = Right
        sf.Trimming = StringTrimming.None
        sf.FormatFlags = sf.FormatFlags Or StringFormatFlags.NoWrap

        ' Draw the text
        Using brush As New SolidBrush(e.ForeColor)
            e.Graphics.DrawString(itemText, e.Font, brush, e.Bounds, sf)
        End Using

        e.DrawFocusRectangle()
    End Sub

    Private Sub cmbBoxFavorites_DropDown(sender As Object, e As EventArgs) Handles cmbBoxFavorites.DropDown
        cmbBoxFavorites.Visible = False
        Dim curWidth As Integer = cmbBoxFavorites.Width
        Dim Lpos As Integer = cmbBoxFavorites.Left
        cmbBoxFavorites.Width = curWidth * 4
        cmbBoxFavorites.Left = Lpos - curWidth * 3
        cmbBoxFavorites.Visible = True
    End Sub

    Private Sub cmbBoxFavorites_DropDownClosed(sender As Object, e As EventArgs) Handles cmbBoxFavorites.DropDownClosed
        cmbBoxFavorites.Visible = False
        Dim curWidth As Integer = cmbBoxFavorites.Width
        Dim Lpos As Integer = cmbBoxFavorites.Left
        cmbBoxFavorites.Width = curWidth / 4
        cmbBoxFavorites.Left = Lpos + curWidth * (3 / 4)
        cmbBoxFavorites.Visible = True
    End Sub

    Private Sub tbSearchFolder_TextChanged(sender As Object, e As EventArgs) Handles tbSearchFolder.TextChanged
        If _initialized = True Then
            btnUnfavoriteFolder.Hide()
            btnFavoriteFolder.Show()
            btnChangeFileName.Show()
            btnChangeFolderName.Hide()
        End If
    End Sub

    Private Sub cbShowHelp_CheckedChanged(sender As Object, e As EventArgs) Handles cbShowHelp.CheckedChanged
        Try
            If _initialized = True Then
                If cbShowHelp.Checked = True Then
                    cbShowHelp.BackColor = Color.FromArgb(255, 255, 225)
                    Dim md As New MarkDown_To_RTB
                    md._LineSpacingInPts = 4
                    md._DefaultFontSize = 12
                    md._LeftMarginShift = 2
                    Dim helpText As String = My.Computer.FileSystem.ReadAllText(_ini.EXEfolder & "\resources\Usage.md")
                    md.RenderMarkdown(_rtbHelpBox, helpText)
                    md.ShiftRTBbounds(_rtbHelpBox, 8, 4, 8, 4)
                    _rtbHelpBox.Show()
                Else
                    cbShowHelp.BackColor = Color.FromArgb(253, 253, 253)
                    _rtbHelpBox.Hide()
                End If
            End If
        Catch ex As Exception
            MessageBoxCustom.Show(Me, "Error showing help text. File is likely missing.", "ERROR", MessageBoxButtons.OK, MessageBoxIcon.Error, _DPI, "criticalStop")
        End Try

    End Sub

    Private Sub lvMain_ColumnClick(sender As Object, e As ColumnClickEventArgs) Handles lvMain.ColumnClick
        _pathList.ColumnSortHandler(sender, e)
    End Sub

    Private Sub lvMain_MouseDown(sender As Object, e As MouseEventArgs) Handles lvMain.MouseDown
        _pathList.RightClickHandler(sender, e)
    End Sub

    Private Sub lvMain_SelectedIndexChanged(sender As Object, e As EventArgs) Handles lvMain.SelectedIndexChanged
        If lvMain.SelectedItems.Count <> 1 Then Exit Sub
        _CurrentLVitem = _pathList.GetSelectedLVitem
        Dim longPath As String = _pathList.GetCellEntry(_CurrentLVitem, "Path")

        Dim fileName As String = Path.GetFileName(longPath)
        _parentPathCharCount = Path.GetDirectoryName(longPath).Length + 1 '+1 for \ character
        _fileNameCharCount = fileName.Length
        _fullPathCharCount = longPath.Length

        tbNewName.Text = fileName
        rtbOriginalName.Text = fileName
        lblCharCountOriginalName.Text = CStr(longPath.Count).PadLeft(4, " ")
        lblCharCountOriginalName2.Text = CStr(fileName.Length).PadLeft(4, " ")

        btnChangeFileName.Show()
        btnChangeFolderName.Hide()

        _FolderInfo = Nothing
        SetStatus("Ready")
    End Sub


    Private Sub tbNewName_TextChanged(sender As Object, e As EventArgs) Handles tbNewName.TextChanged
        Dim str As String = tbNewName.Text

        lblCharCountNewName.Text = CStr(_parentPathCharCount + str.Length).PadLeft(4, " ")
        lblCharCountNewName2.Text = CStr(str.Length).PadLeft(4, " ")
    End Sub

    Private Sub rtbOriginalName_Resize(sender As Object, e As EventArgs) Handles rtbOriginalName.Resize
        CenterRTBvertically(rtbOriginalName)
    End Sub

    Protected Overrides Function ProcessCmdKey(ByRef msg As Message, keyData As Keys) As Boolean
        If keyData = Keys.Tab Then
            If Me.ActiveControl Is btnLeftFolder OrElse Me.ActiveControl Is btnRightFolder OrElse Me.ActiveControl Is lvMain Then
                tbNewName.Focus()
                tbNewName.Select(0, 0)
                Return True  ' True = key press is handled, don't process further
            End If
        End If
        Return MyBase.ProcessCmdKey(msg, keyData)
    End Function


End Class