✨ Add conversion between CRP and MRP

Author: ronisbr

src/ReferenceFrameRotations.jl

@@ -71,6 +71,7 @@ include("./conversions/angleaxis_to_quat.jl")
 include("./conversions/crp_to_angle.jl")
 include("./conversions/crp_to_angleaxis.jl")
 include("./conversions/crp_to_dcm.jl")
+include("./conversions/crp_to_mrp.jl")
 include("./conversions/crp_to_quat.jl")
 include("./conversions/api.jl")
 include("./conversions/dcm_to_angle.jl")
@@ -80,6 +81,7 @@ include("./conversions/dcm_to_mrp.jl")
 include("./conversions/dcm_to_quat.jl")
 include("./conversions/mrp_to_angle.jl")
 include("./conversions/mrp_to_angleaxis.jl")
+include("./conversions/mrp_to_crp.jl")
 include("./conversions/mrp_to_dcm.jl")
 include("./conversions/mrp_to_quat.jl")
 include("./conversions/quat_to_angle.jl")

src/conversions/crp_to_mrp.jl

@@ -0,0 +1,47 @@
+## Description #############################################################################
+#
+# Functions related to the conversion from CRP to MRP.
+#
+############################################################################################
+
+export crp_to_mrp
+
+"""
+    crp_to_mrp(c::CRP) -> MRP
+
+Convert CRP `c` to MRP.
+
+# Examples
+
+```jldoctest
+julia> c = CRP(0.5, 0, 0)
+CRP{Float64}:
+  X : + 0.5
+  Y : + 0.0
+  Z : + 0.0
+
+julia> crp_to_mrp(c)
+MRP{Float64}:
+  X : + 0.236068
+  Y : + 0.0
+  Z : + 0.0
+```
+"""
+function crp_to_mrp(c::CRP)
+    # Equation:
+    #                 c
+    #   MRP = ─────────────────
+    #          1 + √(1 + |c|²)
+    #
+
+    c₁ = c.q1
+    c₂ = c.q2
+    c₃ = c.q3
+
+    norm_q² = c₁^2 + c₂^2 + c₃^2
+
+    k  = 1 / (1 + √(1 + norm_q²))
+
+    return MRP(k * c₁, k * c₂, k * c₃)
+end
+

src/conversions/mrp_to_crp.jl

@@ -0,0 +1,39 @@
+## Description #############################################################################
+#
+# Functions related to the conversion from MRP to CRP.
+#
+############################################################################################
+
+export mrp_to_crp
+
+"""
+    mrp_to_crp(m::MRP) -> CRP
+
+Convert MRP `m` to CRP.
+
+# Examples
+
+```jldoctest
+```
+"""
+function mrp_to_crp(m::MRP)
+    # Equation:
+    #             2m
+    #   CRP = ──────────
+    #          1 - |m|²
+    #
+
+    m₁ = m.q1
+    m₂ = m.q2
+    m₃ = m.q3
+
+    norm_q² = m₁^2 + m₂^2 + m₃^2
+
+    if isapprox(norm_q², 1; atol = 1e-15)
+        throw(ArgumentError("The MRP represents a rotation of 180 degrees, which is a singularity for CRP."))
+    end
+
+    k  = 2 / (1 - norm_q²)
+
+    return CRP(k * m₁, k * m₂, k * m₃)
+end

test/conversions/crp_to_angleaxis.jl

@@ -24,6 +24,6 @@
         eaa = crp_to_angleaxis(c)
         @test eaa isa EulerAngleAxis{T}
 
-        @test isapprox(eaa, eaa_ref; atol = 100 * eps(T))
+        @test isapprox(eaa, eaa_ref; atol = 1000 * eps(T))
     end
 end

test/conversions/crp_to_mrp.jl

@@ -0,0 +1,29 @@
+## Desription ##############################################################################
+#
+# Tests related to conversion from CRP to MRP.
+#
+############################################################################################
+
+# == File: ./src/conversions/crp_to_mrp.jl ================================================
+
+# -- Functions: crp_to_mrp -----------------------------------------------------------------
+
+@testset "CRP => MRP" begin
+    for T in (Float32, Float64)
+        # The conversion is tested by creating CRPs from DCMs and comparing the resulting
+        # MRP against the one obtained directly from the same DCM.
+        a₁ = _rand_ang(T)
+        a₂ = _rand_ang2(T)
+        a₃ = _rand_ang(T)
+
+        D     = angle_to_dcm(a₃, :X) * angle_to_dcm(a₂, :Y) * angle_to_dcm(a₁, :Z)
+        c     = dcm_to_crp(D)
+        m_ref = dcm_to_mrp(D)
+
+        # Convert CRP to MRP.
+        m = crp_to_mrp(c)
+        @test m isa MRP{T}
+
+        @test isapprox(m, m_ref; atol = 100 * eps(T))
+    end
+end

test/conversions/mrp_to_crp.jl

@@ -0,0 +1,35 @@
+## Desription ##############################################################################
+#
+# Tests related to conversion from MRP to CRP.
+#
+############################################################################################
+
+# == File: ./src/conversions/mrp_to_crp.jl ================================================
+
+# -- Functions: mrp_to_crp -----------------------------------------------------------------
+
+@testset "MRP => CRP" begin
+    for T in (Float32, Float64)
+        # The conversion is tested by creating MRPs from DCMs and comparing the resulting
+        # CRP against the one obtained directly from the same DCM.
+        a₁ = _rand_ang(T)
+        a₂ = _rand_ang2(T)
+        a₃ = _rand_ang(T)
+
+        D     = angle_to_dcm(a₃, :X) * angle_to_dcm(a₂, :Y) * angle_to_dcm(a₁, :Z)
+        m     = dcm_to_mrp(D)
+        c_ref = dcm_to_crp(D)
+
+        # Convert MRP to CRP.
+        c = mrp_to_crp(m)
+        @test c isa CRP{T}
+
+        @test isapprox(c, c_ref; atol = 100 * eps(T), rtol = 100 * eps(T))
+    end
+end
+
+@testset "MRP => CRP (Singularity)" begin
+    # A 180° rotation is a singularity for the CRP (MRP with |m| = 1).
+    m = MRP(1.0, 0.0, 0.0)
+    @test_throws ArgumentError mrp_to_crp(m)
+end

test/runtests.jl

@@ -128,6 +128,7 @@ println("")
     include("./conversions/crp_to_angle.jl")
     include("./conversions/crp_to_angleaxis.jl")
     include("./conversions/crp_to_dcm.jl")
+    include("./conversions/crp_to_mrp.jl")
     include("./conversions/crp_to_quat.jl")
     include("./conversions/dcm_to_angleaxis.jl")
     include("./conversions/dcm_to_angle.jl")
@@ -136,6 +137,7 @@ println("")
     include("./conversions/dcm_to_quaternion.jl")
     include("./conversions/mrp_to_angle.jl")
     include("./conversions/mrp_to_angleaxis.jl")
+    include("./conversions/mrp_to_crp.jl")
     include("./conversions/mrp_to_dcm.jl")
     include("./conversions/mrp_to_quat.jl")
     include("./conversions/quaternion_to_angle.jl")